Attribute VB_Name = "modHwpToPdf"
Option Explicit
' Æú´õ ¾È HWP/HWPX ¸¦ PDF ·Î ÀÏ°ý º¯È¯ÇÏ°í 'º¯È¯ °á°ú' ½ÃÆ®¿¡ ±â·ÏÇÑ´Ù.
' [°³¼±] ÇÑ±Û º¸¾È¸ðµâ µî·Ï+â ¼û±è(ÆÄÀϸ¶´Ù ½ÂÀÎ⡤ÇѱÛ⠶ߴø ¹®Á¦), ÆÄÀϺ° ¿À·ù ó¸®(ÇÑ ÆÄÀÏ ¿À·ù·Î Áß´Ü¡¤ÇÑ±Û ÀÜ·ù ¹æÁö),
'        ÀÓ½ÃÆÄÀÏ(~$) Á¦¿Ü, ÁøÇà·ü, ¼º°ø/½ÇÆÐ Áý°è. ¸®º»¿¡¼­ ¾²Áö ¾Ê´Â Acrobat º´ÇÕ Sub »èÁ¦(PDF º´ÇÕÀº modMergePdf).
' [v2.6] HP_Run(mode): 1 °¢°¢ÀÇ PDF / 2 ÇϳªÀÇ PDF(¸ñÂ÷¡¤¸µÅ©) / 3 ÇϳªÀÇ PDF(ÆÄÀϸ¸) - 2¡¤3Àº Àӽà Æú´õ¿¡ º¯È¯ ÈÄ modMergePdf.MP_MergeFiles ·Î ÇÕħ

Public HP_TestFolder As String   ' °ËÁõ¿ë: ÁöÁ¤µÇ¸é Æú´õ ´ëÈ­»óÀÚ »ý·«

Sub dHWP_to_PDF_Converter(control As IRibbonControl)
    HP_Run 1
End Sub

Public Sub HP_Run(ByVal mode As Long)
    Dim fso As Object, ws As Worksheet, folderPath As String, outFolder As String, total As Long
    Dim pdfPaths() As String, pdfNames() As String, okCount As Long, failCount As Long, savePath As String, t0 As Single, i As Long

    Set fso = CreateObject("Scripting.FileSystemObject")
    If Len(HP_TestFolder) > 0 Then
        folderPath = HP_TestFolder
    Else
        With Application.FileDialog(msoFileDialogFolderPicker)
            .title = "HWP/HWPX ÆÄÀÏÀÌ ÀÖ´Â Æú´õ¸¦ ¼±ÅÃÇϼ¼¿ä"
            If .Show <> -1 Then Exit Sub
            folderPath = .SelectedItems(1)
        End With
    End If
    t0 = Timer
    If mode = 1 Then
        outFolder = folderPath
    Else
        outFolder = fso.BuildPath(folderPath, "_pdfÀÓ½Ã_" & Format$(Now, "hhnnss"))
    End If

    Set ws = HP_ResultSheet(ActiveWorkbook)
    total = HP_ConvertFolder(fso, folderPath, outFolder, ws, pdfPaths, pdfNames, okCount, failCount)
    If total = 0 Then
        MsgBox "¼±ÅÃÇÑ Æú´õ¿¡ HWP/HWPX ÆÄÀÏÀÌ ¾ø½À´Ï´Ù.", vbExclamation, "hwp to pdf"
        Exit Sub
    End If
    If total < 0 Then Exit Sub   ' ÇÑ±Û ¾øÀ½ µî (¸Þ½ÃÁö´Â ¾È¿¡¼­)

    If mode = 1 Then
        ws.Activate
        MsgBox "PDF º¯È¯ÀÌ ³¡³µ½À´Ï´Ù.  (" & Format$(Timer - t0, "0.0") & "ÃÊ)" & vbCrLf & vbCrLf & _
               "¼º°ø: " & okCount & "°³ / ½ÇÆÐ: " & failCount & "°³" & vbCrLf & _
               "PDF ´Â ¿øº»°ú °°Àº Æú´õ¿¡ ÀúÀåµÇ¾ú°í, 'º¯È¯ °á°ú' ½ÃÆ®¿¡¼­ ÆÄÀÏÀ» ¿­ ¼ö ÀÖ½À´Ï´Ù.", _
               IIf(failCount > 0, vbExclamation, vbInformation), "hwp to pdf"
        Exit Sub
    End If

    ' 2¡¤3: º¯È¯µÈ PDF ¸¦ Çϳª·Î ÇÕÄ¡±â
    If okCount = 0 Then
        MsgBox "PDF ·Î º¯È¯µÈ ÆÄÀÏÀÌ ¾ø¾î ÇÕÄ¡Áö ¸øÇß½À´Ï´Ù. 'º¯È¯ °á°ú' ½ÃÆ®¸¦ È®ÀÎÇϼ¼¿ä.", vbExclamation, "hwp to pdf"
        On Error Resume Next: fso.DeleteFolder outFolder, True: On Error GoTo 0
        ws.Activate
        Exit Sub
    End If
    If mode = 2 Then
        savePath = fso.BuildPath(folderPath, "º´ÇÕ_¸ñÂ÷_" & Format$(Now, "yyyymmdd_hhnnss") & ".pdf")
    Else
        savePath = fso.BuildPath(folderPath, "º´ÇÕ_" & Format$(Now, "yyyymmdd_hhnnss") & ".pdf")
    End If
    If MP_MergeFiles(fso, pdfPaths, pdfNames, okCount, (mode = 2), savePath) Then
        ws.Range("A1").value = "ÇÕÄ£ PDF"
        ws.Hyperlinks.Add anchor:=ws.Range("B1"), Address:=savePath, TextToDisplay:=fso.GetFileName(savePath)
        ws.Range("A1").Font.Bold = True
        ws.Columns("A:D").AutoFit
        ws.Activate
        On Error Resume Next
        fso.DeleteFolder outFolder, True
        On Error GoTo 0
        If UI_Choose("hwp to pdf ¿Ï·á", "ÇÑ±Û ÆÄÀÏ " & okCount & "°³¸¦ PDF ·Î º¯È¯ÇØ Çϳª·Î ÇÕÃƽÀ´Ï´Ù. (" & Format$(Timer - t0, "0.0") & "ÃÊ" & IIf(failCount > 0, ", º¯È¯ ½ÇÆÐ " & failCount & "°³", "") & ")" & vbCrLf & vbCrLf & _
                     "ÀúÀå À§Ä¡: " & savePath & vbCrLf & "(ÆÄÀϺ° °á°ú´Â 'º¯È¯ °á°ú' ½ÃÆ®¿¡ ÀÖ½À´Ï´Ù)", Array("ÇÕÄ£ PDF ¿­±â", "´Ý±â")) = 1 Then
            Shell "explorer """ & savePath & """", vbNormalFocus
        End If
    Else
        ws.Activate
        MsgBox "PDF ÇÕÄ¡±â¿¡ ½ÇÆÐÇß½À´Ï´Ù. º¯È¯µÈ PDF ´Â " & outFolder & " ¿¡ ³²°Ü µÎ¾ú½À´Ï´Ù.", vbExclamation, "hwp to pdf"
    End If
End Sub

' °á°ú ½ÃÆ®: ÀÖÀ¸¸é Àç»ç¿ë, ¾øÀ¸¸é »ý¼º
Private Function HP_ResultSheet(ByVal wb As Workbook) As Worksheet
    Dim ws As Worksheet
    On Error Resume Next
    Set ws = wb.Sheets("º¯È¯ °á°ú")
    On Error GoTo 0
    If ws Is Nothing Then
        Set ws = wb.Sheets.Add(After:=wb.Sheets(wb.Sheets.Count))
        ws.name = "º¯È¯ °á°ú"
    End If
    Set HP_ResultSheet = ws
End Function

' Æú´õ ¾È hwp/hwpx ¡æ outFolder ¿¡ PDF º¯È¯. ¹Ýȯ: ´ë»ó ÆÄÀÏ ¼ö(0=¾øÀ½, -1=ÇÑ±Û ½ÇÇà ºÒ°¡). pdfPaths/pdfNames ´Â ¼º°øÇÑ °Í¸¸(1~okCount)
Public Function HP_ConvertFolder(ByVal fso As Object, ByVal folderPath As String, ByVal outFolder As String, ByVal ws As Worksheet, _
                                 ByRef pdfPaths() As String, ByRef pdfNames() As String, ByRef okCount As Long, ByRef failCount As Long) As Long
    Dim folder As Object, file As Object, objHwp As Object
    Dim filePath As String, pdfPath As String, ext As String
    Dim row As Long, total As Long, Done As Long, opened As Boolean
    Dim names() As String, paths() As String, i As Long, j As Long, T As String

    Set folder = fso.GetFolder(folderPath)
    For Each file In folder.files
        ext = LCase$(fso.GetExtensionName(file.name))
        If (ext = "hwp" Or ext = "hwpx") And Left$(file.name, 2) <> "~$" And Left$(file.name, 3) <> "º´ÇÕ_" Then
            total = total + 1
            ReDim Preserve names(1 To total): ReDim Preserve paths(1 To total)
            names(total) = file.name: paths(total) = file.path
        End If
    Next file
    If total = 0 Then Exit Function
    ' À̸§¼ø Á¤·Ä
    For i = 1 To total - 1
        For j = 1 To total - i
            If StrComp(names(j), names(j + 1), vbTextCompare) > 0 Then
                T = names(j): names(j) = names(j + 1): names(j + 1) = T
                T = paths(j): paths(j) = paths(j + 1): paths(j + 1) = T
            End If
        Next j
    Next i

    On Error Resume Next
    Set objHwp = CreateObject("HWPFrame.HwpObject")
    On Error GoTo 0
    If objHwp Is Nothing Then
        MsgBox "ÇÑ±Û ÇÁ·Î±×·¥À» ½ÇÇàÇÒ ¼ö ¾ø½À´Ï´Ù. ÇѱÛ(HWP)ÀÌ ¼³Ä¡µÇ¾î ÀÖ´ÂÁö È®ÀÎÇϼ¼¿ä.", vbCritical, "hwp to pdf"
        HP_ConvertFolder = -1
        Exit Function
    End If
    On Error Resume Next
    objHwp.RegisterModule "FilePathCheckDLL", "FilePathCheckerModule"
    objHwp.XHwpWindows.item(0).Visible = False
    If Not fso.FolderExists(outFolder) Then fso.CreateFolder outFolder
    On Error GoTo 0

    ws.cells.Clear
    ws.Range("A2").value = "Æú´õ°æ·Î"
    ws.Hyperlinks.Add anchor:=ws.Range("B2"), Address:=folderPath, TextToDisplay:=folderPath
    ws.Range("A3").value = "No.": ws.Range("B3").value = "¿øº» ÆÄÀϸí (HWP)"
    ws.Range("C3").value = "º¯È¯ °á°ú": ws.Range("D3").value = "º¯È¯µÈ ÆÄÀÏ (PDF)"
    With ws.Range("A2:D3")
        .Font.Bold = True
        .Interior.color = RGB(220, 230, 241)
        .HorizontalAlignment = xlCenter
    End With
    row = 4
    ReDim pdfPaths(1 To total): ReDim pdfNames(1 To total)

    Application.ScreenUpdating = False
    For i = 1 To total
        Done = Done + 1
        Application.StatusBar = "PDF º¯È¯ Áß " & Done & "/" & total & " : " & names(i)
        DoEvents
        filePath = paths(i)
        pdfPath = fso.BuildPath(outFolder, fso.GetBaseName(names(i)) & ".pdf")
        If fso.FileExists(pdfPath) And outFolder <> folderPath Then pdfPath = fso.BuildPath(outFolder, fso.GetBaseName(names(i)) & "_" & Format$(i, "000") & ".pdf")
        ws.cells(row, "A").value = row - 3
        ws.Hyperlinks.Add anchor:=ws.cells(row, "B"), Address:=filePath, TextToDisplay:=names(i)

        On Error Resume Next
        Err.Clear
        opened = (objHwp.Open(filePath, "", "forceopen:true") <> 0)
        If Err.Number <> 0 Then opened = False
        If opened Then
            Err.Clear
            If (objHwp.SaveAs(pdfPath, "PDF", "") <> 0) And Err.Number = 0 And fso.FileExists(pdfPath) Then
                ws.cells(row, "C").value = "¼º°ø"
                ws.cells(row, "C").Font.color = RGB(0, 176, 80)
                ws.Hyperlinks.Add anchor:=ws.cells(row, "D"), Address:=pdfPath, TextToDisplay:=fso.GetFileName(pdfPath)
                okCount = okCount + 1
                pdfPaths(okCount) = pdfPath
                pdfNames(okCount) = fso.GetBaseName(names(i))
            Else
                ws.cells(row, "C").value = "º¯È¯ ½ÇÆÐ" & IIf(Err.Number <> 0, ": " & Err.Description, "")
                ws.cells(row, "C").Font.color = RGB(255, 0, 0)
                failCount = failCount + 1
            End If
            objHwp.Clear 1
        Else
            ws.cells(row, "C").value = "ÆÄÀÏ ¿­±â ½ÇÆÐ" & IIf(Err.Number <> 0, ": " & Err.Description, "")
            ws.cells(row, "C").Font.color = RGB(255, 0, 0)
            failCount = failCount + 1
        End If
        On Error GoTo 0
        row = row + 1
    Next i

    On Error Resume Next
    objHwp.Quit
    Set objHwp = Nothing
    On Error GoTo 0
    ws.Columns("A:D").AutoFit
    Application.StatusBar = False
    Application.ScreenUpdating = True
    HP_ConvertFolder = total
End Function