Attribute VB_Name = "modHwpKeywordSheet"
Option Explicit
' =====================================================================================
'  modHwpKeywordSheet : ÇѱÛ(HWP/HWPX)¡¤PDF Å°¿öµå°ª °¡Á®¿À±â (½ÃÆ® ¹æ½Ä)
'
'  È­¸é ±¸¼º (¸®º» [Å°¿öµå°ª °¡Á®¿À±â] Ŭ¸¯ ½Ã »ý¼º)
'    1Çà : [1 Æú´õ¼±ÅÃ] [2 Å°¿öµå°ª °¡Á®¿À±â] µµÇü ¹öÆ°
'    A2  : "´ë»óÆú´õ"      B2 : Æú´õ ¸µÅ©(Ŭ¸¯ ½Ã Ž»ö±â)
'    A3  : "ÃâóÆÄÀϸí(ÆäÀÌÁö)"  B3~J3 : Å°¿öµå1~9 (»ç¿ëÀÚ°¡ µ¤¾î½á¼­ ÀÔ·Â)
'    4Çà~: ÆÄÀϺ° 1Çà. A=ÆÄÀÏ¸í ¸µÅ©(°ªÀ» ãÀº ÆäÀÌÁö), B~J=Å°¿öµåº° °ª
'
'  °ª ÆǺ° ±ÔÄ¢ (¹®¼­ ¼ø¼­´ë·Î ù ¹ø° ÀÏÄ¡)
'    Ç¥ ¾È¿¡¼­ Å°¿öµå ¼¿À» ãÀ¸¸é
'      ¨ç °°Àº ¼¿¿¡ "Å°¿öµå: °ª" ÇüÅÂ¸é ±× °ª
'      ¨è ¿À¸¥ÂÊ ¼¿ÀÌ °ªÀÌ¸é ¿À¸¥ÂÊ   (º´ÇÕ ¼¿Àº °Ç³Ê¶Ù¾î ´ÙÀ½ ½ÇÁ¦ ¼¿)
'      ¨é ¿À¸¥ÂÊÀÌ ºñ¾ú°Å³ª ´Ù¸¥ Å°¿öµå¸é ¾Æ·¡ ¼¿
'      ¨ê µÑ ´Ù ¾Æ´Ï¸é ´ÙÀ½ ÀÏÄ¡ À§Ä¡¸¦ °è¼Ó Ž»ö
'    ¹®´Ü¿¡¼­´Â "Å°¿öµå : °ª" ÀÇ °ª, ¾øÀ¸¸é ¹Ù·Î ´ÙÀ½ ÁÙ
'    "°ª"ÀÇ ±âÁØ : ºñ¾î ÀÖÁö ¾Ê°í, »ç¿ëÀÚ°¡ ÀÔ·ÂÇÑ ´Ù¸¥ Å°¿öµå°¡ ¾Æ´Ñ °Í
'
'  ±¸Á¶ Àбâ : hwpx ¡æ XML Ç¥ ±¸Á¶ / hwp ¡æ Çѱ۷Πhwpx Àӽà º¯È¯ / pdf ¡æ Word Ç¥ °´Ã¼
' =====================================================================================
Private Const KW_FIRST_COL As Long = 2      ' B
Private Const KW_LAST_COL As Long = 10      ' J
Private Const DATA_ROW As Long = 4
Private Const MAX_VALUE_LEN As Long = 200
Private hkNote As String   ' ÆÄÀϺ° ó¸® »óÅ ¸Þ¸ð
Private hkFuzzy As Boolean ' [v2.7] OCR ¹®¼­: Å°¿öµå 1±ÛÀÚ ¿ÀÂ÷ Çã¿ë

' ---- ¹®¼­ ±¸Á¶ (ÆÄÀÏ 1°³ ºÐ·®, ¸ðµâ º¯¼ö) ----
Private Type HKTable
    nRows As Long
    nCols As Long
    txt() As String
    cid() As Long
    page As Long
End Type
Private tbls() As HKTable
Private tblCount As Long
Private lines() As String
Private linePage() As Long
Private lineCount As Long
Private blocks() As Long        ' ¹®¼­ ¼ø¼­: ¾ç¼ö=¹®´Ü index, À½¼ö=-Ç¥ index
Private blockCount As Long
Private cellSeq As Long

' =====================================================================================
'  [¸®º»] È­¸é ¸¸µé±â
' =====================================================================================
Public Sub HK_Start(control As IRibbonControl)
    Dim ws As Worksheet, i As Long
    Set ws = HK_NewSheet(ActiveWorkbook)
    HK_CreateButtons ws
    ws.Range("A2").value = "´ë»óÆú´õ: (1 Æú´õ¼±Åà ¹öÆ°À» ´©¸£¼¼¿ä)"
    ws.Range("A3").value = "ÃâóÆÄÀϸí(ÆäÀÌÁö)"
    For i = KW_FIRST_COL To KW_LAST_COL
        ws.cells(3, i).value = "Å°¿öµå" & (i - KW_FIRST_COL + 1)
        ws.cells(3, i).Font.color = RGB(150, 150, 150)
    Next i
    With ws.Range(ws.cells(2, 1), ws.cells(3, KW_LAST_COL))
        .Font.name = "¸¼Àº °íµñ"
        .Font.Size = 11
    End With
    ws.Range("A2:A3").Font.Bold = True
    ws.Range("A2:A3").Interior.color = RGB(221, 235, 247)
    With ws.Range(ws.cells(3, KW_FIRST_COL), ws.cells(3, KW_LAST_COL))
        .Interior.color = RGB(255, 242, 204)
        .Borders.LineStyle = xlContinuous
        .HorizontalAlignment = xlCenter
    End With
    ws.Range("A3").Borders.LineStyle = xlContinuous
    ws.Columns("A").ColumnWidth = 30
    ws.Range(ws.Columns(KW_FIRST_COL), ws.Columns(KW_LAST_COL)).ColumnWidth = 16
    ws.Range("A5").value = "»ç¿ë ¼ø¼­:  ¨ç [1 Æú´õ¼±ÅÃ]  ¨è 3Çà B~J¿¡ ãÀ» Å°¿öµå ÀÔ·Â(¿¹: ¼º¸í, °èÁ¹øÈ£)  ¨é [2 Å°¿öµå°ª °¡Á®¿À±â]"
    ws.Range("A6").value = "°ª À§Ä¡´Â ÀÚµ¿ ÆǺ°ÇÕ´Ï´Ù: °°Àº ¼¿(Å°¿öµå: °ª) ¡æ ¿À¸¥ÂÊ ¼¿ ¡æ ¾Æ·¡ ¼¿ ¡æ ¹®´ÜÀÇ Å°¿öµå µÚ / ´ÙÀ½ ÁÙ"
    ws.Range("A5:A6").Font.color = RGB(100, 100, 100)
    ws.Range("A5:A6").Font.Size = 10
    ws.Activate
    ws.Range("B3").Select
End Sub

Private Function HK_NewSheet(ByVal wb As Workbook) As Worksheet
    Dim nm As String, n As Long, exist As Worksheet
    nm = "Å°¿öµå°ª"
    Do
        Set exist = Nothing
        On Error Resume Next
        Set exist = wb.Worksheets(nm)
        On Error GoTo 0
        If exist Is Nothing Then Exit Do
        n = n + 1
        nm = "Å°¿öµå°ª_" & n
    Loop
    Set HK_NewSheet = wb.Worksheets.Add(After:=wb.Worksheets(wb.Worksheets.Count))
    HK_NewSheet.name = nm
End Function

Private Sub HK_CreateButtons(ByVal ws As Worksheet)
    Dim s As Shape, i As Long, names As Variant, captions As Variant, actions As Variant
    names = Array("btnHkFolder", "btnHkExtract")
    captions = Array("1 Æú´õ¼±ÅÃ", "2 Å°¿öµå°ª °¡Á®¿À±â")
    actions = Array("HK_PickFolder", "HK_Extract")
    ws.rows(1).RowHeight = 42
    For i = 0 To 1
        On Error Resume Next
        ws.Shapes(CStr(names(i))).Delete
        On Error GoTo 0
        Set s = ws.Shapes.AddShape(msoShapeRoundedRectangle, 5 + i * 150, 6, 140, 30)
        s.name = CStr(names(i))
        UI_StyleButton s, CStr(captions(i)), CStr(actions(i)), i = 1
    Next i
End Sub

' =====================================================================================
'  [¹öÆ° 1] Æú´õ ¼±Åà ¡æ B2 ¸µÅ©
' =====================================================================================
Public Sub HK_PickFolder()
    Dim ws As Worksheet, fldr As String, fso As Object, f As Object, n As Long
    Set ws = ActiveSheet
    With Application.FileDialog(msoFileDialogFolderPicker)
        .title = "HWP / HWPX / PDF ÆÄÀÏÀÌ ÀÖ´Â Æú´õ¸¦ ¼±ÅÃÇϼ¼¿ä"
        If .Show <> -1 Then Exit Sub
        fldr = .SelectedItems(1)
    End With
    Set fso = CreateObject("Scripting.FileSystemObject")
    For Each f In fso.GetFolder(fldr).files
        If HK_IsSupported(f.name) Then n = n + 1
    Next f
    ws.Range("A2").Hyperlinks.Delete
    ws.Range("A2").value = "´ë»óÆú´õ: " & fldr                 ' 09-29: ¸µÅ©´Â A2 (Å°¿öµå1 ¿­ÀÌ ³Ð¾îÁöÁö ¾Ê°Ô)
    ws.Hyperlinks.Add anchor:=ws.Range("A2"), Address:=fldr, TextToDisplay:="´ë»óÆú´õ: " & fldr, ScreenTip:="Ŭ¸¯Çϸé Ž»ö±â¿¡¼­ Æú´õ¸¦ ¿±´Ï´Ù"
    ws.Range("A2").Font.Bold = True
    ws.Range("B2").value = "´ë»ó ÆÄÀÏ " & n & "°³"
    ws.Range("B2").Font.color = RGB(100, 100, 100)
    If n = 0 Then MsgBox "¼±ÅÃÇÑ Æú´õ¿¡ hwp/hwpx/pdf ÆÄÀÏÀÌ ¾ø½À´Ï´Ù.", vbExclamation, "Å°¿öµå°ª °¡Á®¿À±â"
End Sub

' =====================================================================================
'  [¹öÆ° 2] Å°¿öµå°ª °¡Á®¿À±â
' =====================================================================================
Public Sub HK_Extract()
    Dim ws As Worksheet, fldr As String, kws() As String, kwCols() As Long, kwCount As Long
    Dim fso As Object, f As Object, files As Collection, r As Long, i As Long, k As Long
    Dim hwp As Object, wdApp As Object, ext As String, ok As Boolean, v As String
    Dim pages As Object, pageList As String, hwpPage As Long, t0 As Single
    Dim errMsg As String, errFile As String
    Set ws = ActiveSheet
    ws.cells(3, 12).value = "ó¸® »óÅÂ"
    fldr = HK_FolderOf(ws)
    If Len(fldr) = 0 Then
        MsgBox "¸ÕÀú [1 Æú´õ¼±ÅÃ] ¹öÆ°À¸·Î ´ë»ó Æú´õ¸¦ ÁöÁ¤Çϼ¼¿ä.", vbExclamation, "Å°¿öµå°ª °¡Á®¿À±â"
        Exit Sub
    End If
    kwCount = HK_ReadKeywords(ws, kws, kwCols)
    If kwCount = 0 Then
        MsgBox "3Çà B~J Ä­¿¡ ãÀ» Å°¿öµå¸¦ ÀÔ·ÂÇϼ¼¿ä. (¿¹: ¼º¸í, °èÁ¹øÈ£, ¿¬¶ôó)", vbExclamation, "Å°¿öµå°ª °¡Á®¿À±â"
        ws.Range("B3").Select
        Exit Sub
    End If
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set files = New Collection
    For Each f In fso.GetFolder(fldr).files
        If HK_IsSupported(f.name) Then files.Add f.path
    Next f
    If files.Count = 0 Then
        MsgBox "´ë»ó Æú´õ¿¡ hwp/hwpx/pdf/À̹ÌÁö(png¡¤jpg) ÆÄÀÏÀÌ ¾ø½À´Ï´Ù.", vbExclamation, "Å°¿öµå°ª °¡Á®¿À±â"
        Exit Sub
    End If
    On Error GoTo HK_Fail   ' [¼öÁ¤] ÆÄÀÏ ÇϳªÀÇ ¿¹±âÄ¡ ¾ÊÀº ¿À·ù·Î ÇѱÛ/¿öµå ÇÁ·Î¼¼½º°¡ ³²Áö ¾Êµµ·Ï
    ' ÀÌÀü °á°ú Áö¿ì±â
    With ws.Range(ws.cells(DATA_ROW, 1), ws.cells(ws.rows.Count, KW_LAST_COL))
        .Hyperlinks.Delete
        .Clear
    End With
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
    t0 = Timer
    r = DATA_ROW
    For i = 1 To files.Count
        Application.StatusBar = "Å°¿öµå°ª °¡Á®¿À±â " & i & "/" & files.Count & " : " & fso.GetFileName(files(i))
        DoEvents
        ext = LCase$(fso.GetExtensionName(files(i)))
        ok = False
        Set pages = CreateObject("Scripting.Dictionary")
        If ext = "hwpx" Then
            ok = HK_LoadHwpx(files(i))
        ElseIf ext = "hwp" Then
            If hwp Is Nothing Then Set hwp = HK_CreateHwp()
            If hwp Is Nothing Then
                ws.cells(r, KW_FIRST_COL).value = "ÇѱÛ(HWP) ÇÁ·Î±×·¥À» ãÀ» ¼ö ¾ø½À´Ï´Ù"
            Else
                ok = HK_LoadHwpViaHwpx(files(i), hwp, fso)
            End If
        ElseIf ext = "pdf" Then
            If wdApp Is Nothing Then Set wdApp = HK_CreateWord()
            If wdApp Is Nothing Then
                ws.cells(r, KW_FIRST_COL).value = "Word ÇÁ·Î±×·¥À» ãÀ» ¼ö ¾ø½À´Ï´Ù(PDF º¯È¯¿ë)"
            Else
                ok = HK_LoadPdfViaWord(files(i), wdApp)
            End If
        ElseIf HK_IsImage(ext) Then
            ok = HK_LoadImageViaOcr(files(i), fso)
            If Not ok Then ws.cells(r, KW_FIRST_COL).value = "OCR ½ÇÆÐ: Windows 10 ÀÌ»ó + Çѱ¹¾î ¾ð¾îÆÑ(OCR) ÇÊ¿ä"
        End If
        If ok Then
            For k = 1 To kwCount
                v = HK_FindValue(kws(k), kws, kwCount, hwpPage)
                ws.cells(r, kwCols(k)).NumberFormat = "@"
                ws.cells(r, kwCols(k)).value = v
                If Len(v) > 0 Then
                    If ext = "hwp" And Not hwp Is Nothing Then hwpPage = HK_HwpPageOf(hwp, kws(k))
                    If hwpPage > 0 Then pages(hwpPage) = 1
                End If
            Next k
            If ext = "hwp" And Not hwp Is Nothing Then HK_HwpClose hwp
        End If
        pageList = HK_PageText(pages)
        ws.cells(r, 12).value = ext & IIf(ok, " Àб⠼º°ø(" & tblCount & "Ç¥/" & lineCount & "ÁÙ)", " Àб⠽ÇÆÐ") & IIf(Len(hkNote) > 0, " " & hkNote, "")
        hkNote = ""
        ws.cells(r, 1).value = fso.GetFileName(files(i)) & IIf(Len(pageList) > 0, " (" & pageList & ")", "")
        On Error Resume Next
        ws.Hyperlinks.Add anchor:=ws.cells(r, 1), Address:=files(i), TextToDisplay:=CStr(ws.cells(r, 1).value)
        On Error GoTo 0
        r = r + 1
    Next i
    HK_FormatResult ws, r - 1, kwCols, kwCount
    On Error Resume Next
    If Not hwp Is Nothing Then hwp.Quit
    If Not wdApp Is Nothing Then wdApp.Quit
    On Error GoTo 0
    Application.StatusBar = False
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True
    MsgBox "¿Ï·á: ÆÄÀÏ " & files.Count & "°³, Å°¿öµå " & kwCount & "°³ (" & Format$(Timer - t0, "0.0") & "ÃÊ)" & vbCrLf & vbCrLf & _
           "ºó Ä­Àº ¹®¼­¿¡¼­ °ªÀ» ãÁö ¸øÇÑ °æ¿ìÀÔ´Ï´Ù. Å°¿öµå Ç¥±â(¶ç¾î¾²±â¡¤°ýÈ£)¸¦ ¹®¼­¿Í ¸ÂÃç ´Ù½Ã ½ÇÇàÇØ º¸¼¼¿ä.", vbInformation, "Å°¿öµå°ª °¡Á®¿À±â"
    Exit Sub
HK_Fail:
    errMsg = Err.Description
    On Error Resume Next
    errFile = fso.GetFileName(files(i))
    If Not hwp Is Nothing Then HK_HwpClose hwp: hwp.Quit
    If Not wdApp Is Nothing Then wdApp.Quit
    Application.StatusBar = False
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True
    MsgBox "ÆÄÀÏ Ã³¸® Áß ¿À·ù°¡ ³ª¼­ Áß´ÜÇß½À´Ï´Ù." & vbCrLf & vbCrLf & _
           "ÆÄÀÏ: " & errFile & vbCrLf & "¿À·ù: " & errMsg & vbCrLf & vbCrLf & _
           "ÀÌ ÆÄÀÏ ¾Õ±îÁöÀÇ °á°ú´Â ½ÃÆ®¿¡ ³²¾Æ ÀÖ½À´Ï´Ù. ¹®Á¦ ÆÄÀÏÀ» Æú´õ¿¡¼­ »©°í ´Ù½Ã ½ÇÇàÇϼ¼¿ä.", vbExclamation, "Å°¿öµå°ª °¡Á®¿À±â"
End Sub

Private Function HK_FolderOf(ByVal ws As Worksheet) As String
    ' 09-29: Æú´õ ¸µÅ©´Â A2("´ë»óÆú´õ: °æ·Î"). ¿¹Àü ½ÃÆ®(B2 ¸µÅ©)µµ Àд´Ù.
    Dim p As String, cands As Variant, i As Long, a As String
    cands = Array("A2", "B2")
    For i = 0 To 1
        a = CStr(cands(i)): p = ""
        On Error Resume Next
        If ws.Range(a).Hyperlinks.Count > 0 Then p = ws.Range(a).Hyperlinks(1).Address
        On Error GoTo 0
        If Len(p) = 0 Then p = Trim$(CStr(ws.Range(a).value))
        If Left$(p, 5) = "´ë»óÆú´õ:" Then p = Trim$(Mid$(p, 6))
        If Len(p) > 0 Then
            If dir(p, vbDirectory) <> "" And InStr(p, "\") > 0 Then HK_FolderOf = p: Exit Function
        End If
    Next i
    HK_FolderOf = ""
End Function

Private Function HK_ReadKeywords(ByVal ws As Worksheet, ByRef kws() As String, ByRef kwCols() As Long) As Long
    Dim c As Long, n As Long, s As String
    ReDim kws(1 To KW_LAST_COL): ReDim kwCols(1 To KW_LAST_COL)
    For c = KW_FIRST_COL To KW_LAST_COL
        s = Trim$(CStr(ws.cells(3, c).value))
        If Len(s) > 0 And Not (Left$(s, 3) = "Å°¿öµå" And IsNumeric(Mid$(s, 4)) And ws.cells(3, c).Font.color = RGB(150, 150, 150)) Then   ' ȸ»ö ÀÚ¸®Ç¥½ÃÀÚ¸¸ °Ç³Ê¶Ü
            n = n + 1
            kws(n) = s: kwCols(n) = c
            ws.cells(3, c).Font.color = RGB(0, 0, 0)
        End If
    Next c
    HK_ReadKeywords = n
End Function

Private Function HK_IsSupported(ByVal name As String) As Boolean
    Dim e As String
    If Left$(name, 2) = "~$" Then Exit Function
    e = LCase$(Mid$(name, InStrRev(name, ".") + 1))
    HK_IsSupported = (e = "hwp" Or e = "hwpx" Or e = "pdf" Or HK_IsImage(e))
End Function

Private Function HK_IsImage(ByVal e As String) As Boolean
    HK_IsImage = (e = "png" Or e = "jpg" Or e = "jpeg" Or e = "bmp" Or e = "tif" Or e = "tiff" Or e = "gif")
End Function

Private Function HK_PageText(ByVal pages As Object) As String
    Dim keys As Variant, i As Long, j As Long, T As Variant, s As String
    If pages.Count = 0 Then Exit Function
    keys = pages.keys
    For i = 0 To UBound(keys) - 1
        For j = i + 1 To UBound(keys)
            If keys(j) < keys(i) Then T = keys(i): keys(i) = keys(j): keys(j) = T
        Next j
    Next i
    For i = 0 To UBound(keys)
        s = s & IIf(i > 0, ",", "") & keys(i)
    Next i
    HK_PageText = "p." & s
End Function

Private Sub HK_FormatResult(ByVal ws As Worksheet, ByVal lastRow As Long, ByRef kwCols() As Long, ByVal kwCount As Long)
    Dim rng As Range, r As Long
    If lastRow < DATA_ROW Then Exit Sub
    Set rng = ws.Range(ws.cells(DATA_ROW, 1), ws.cells(lastRow, KW_LAST_COL))
    rng.Font.name = "¸¼Àº °íµñ"
    rng.Font.Size = 11
    rng.Borders.LineStyle = xlContinuous
    rng.Borders.color = RGB(191, 191, 191)
    rng.VerticalAlignment = xlCenter
    For r = DATA_ROW To lastRow
        If r Mod 2 = 0 Then ws.Range(ws.cells(r, 1), ws.cells(r, KW_LAST_COL)).Interior.color = RGB(242, 242, 242)
    Next r
    ws.Range(ws.Columns(KW_FIRST_COL), ws.Columns(KW_LAST_COL)).AutoFit
    HK_CapWidths ws
    ' (A5:A6 ¾È³»¹®Àº °á°ú ¿µ¿ª Clear ¶§ ÀÌ¹Ì Áö¿öÁü - ¿©±â¼­ Áö¿ì¸é 5¡¤6Çà ÆÄÀϸíÀÌ »ç¶óÁö´Â ¹ö±×¿´À½)
End Sub

' =====================================================================================
'  °ª ã±â (¹®¼­ ±¸Á¶ »ç¿ë)
' =====================================================================================
Private Function HK_FindValue(ByVal kw As String, ByRef kws() As String, ByVal kwCount As Long, ByRef pageOut As Long) As String
    Dim b As Long, idx As Long, v As String
    pageOut = 0
    For b = 1 To blockCount
        idx = blocks(b)
        If idx < 0 Then
            v = HK_SearchTable(-idx, kw, kws, kwCount)
            If Len(v) > 0 Then pageOut = tbls(-idx).page
        Else
            v = HK_SearchLine(idx, kw, kws, kwCount)
            If Len(v) > 0 Then pageOut = linePage(idx)
        End If
        If Len(v) > 0 Then Exit For
    Next b
    HK_FindValue = HK_Clean(v, kw, kws, kwCount)
End Function

Private Function HK_SearchTable(ByVal ti As Long, ByVal kw As String, ByRef kws() As String, ByVal kwCount As Long) As String
    Dim r As Long, c As Long, cc As Long, rr As Long, cellText As String, v As String, kn As String
    Dim vR As String, vB As String, rowKw As Long, colKw As Long, belowFirst As Boolean
    kn = HK_Norm(kw)
    If Len(kn) = 0 Then Exit Function
    With tbls(ti)
        For r = 1 To .nRows
            For c = 1 To .nCols
                cellText = .txt(r, c)
                If hkFuzzy Then cellText = HK_FuzzyFix(cellText, kw)
                If HK_IsKeywordCell(cellText, kw, kn) Then
                    ' ¨ç °°Àº ¼¿ "Å°¿öµå: °ª"
                    v = HK_AfterKeyword(cellText, kw)
                    If HK_IsValue(v, kws, kwCount) Then HK_SearchTable = v: Exit Function
                    ' ¿À¸¥ÂÊ ¼¿ / ¾Æ·¡ ¼¿ (º´ÇÕµÈ °°Àº ¼¿Àº °Ç³Ê¶Ü)
                    vR = "": vB = ""
                    cc = c + 1
                    Do While cc <= .nCols
                        If .cid(r, cc) <> .cid(r, c) Then Exit Do
                        cc = cc + 1
                    Loop
                    If cc <= .nCols Then vR = .txt(r, cc)
                    rr = r + 1
                    Do While rr <= .nRows
                        If .cid(rr, c) <> .cid(r, c) Then Exit Do
                        rr = rr + 1
                    Loop
                    If rr <= .nRows Then vB = .txt(rr, c)
                    ' [v2.7] ¸Ó¸®±Û Ç¥(Ç׸ñ¸íÀÌ °¡·Î·Î ³ª¿­µÇ°í °ªÀÌ ¾Æ·¡ Çà) ÆǺ°:
                    '   °°Àº ÇàÀÇ ´Ù¸¥ Å°¿öµå ¼ö > °°Àº ¿­ÀÇ ´Ù¸¥ Å°¿öµå ¼ö ¡æ ¾Æ·¡ ¼¿ ¿ì¼±, ¾Æ´Ï¸é ¿À¸¥ÂÊ ¼¿ ¿ì¼±
                    rowKw = HK_CountKw(ti, r, 0, kws, kwCount, c)
                    colKw = HK_CountKw(ti, 0, c, kws, kwCount, r)
                    belowFirst = (rowKw > colKw)
                    ' 09-29: ¼­½ÄÇü Ç¥(¶óº§|°ª|¶óº§|°ª)´Â ¿À¸¥ÂÊ Ä­¿¡ °ªÀÌ ÀÖÀ¸¹Ç·Î, ¿À¸¥ÂÊÀÌ ºñ¾ú°Å³ª ¶óº§/Å°¿öµåÀ̰ųª ¸Ó¸®±Û ÇàÀÏ ¶§¸¸ ¾Æ·¡ Ä­ ¿ì¼±
                    If belowFirst And Len(HK_Norm(vR)) > 0 Then
                        If Not (HK_LooksLabel(vR) Or Not HK_IsValue(vR, kws, kwCount) Or HK_IsAnyKw(vR, kws, kwCount) Or HK_IsHeaderRow(ti, r)) Then belowFirst = False
                    End If
                    If belowFirst Then
                        If HK_IsValue(vB, kws, kwCount) And Not HK_LooksLabel(vB) Then HK_SearchTable = vB: Exit Function
                        If HK_IsValue(vR, kws, kwCount) And Not HK_LooksLabel(vR) Then HK_SearchTable = vR: Exit Function
                        If HK_IsValue(vB, kws, kwCount) Then HK_SearchTable = vB: Exit Function
                    Else
                        If HK_IsValue(vR, kws, kwCount) And Not HK_LooksLabel(vR) Then HK_SearchTable = vR: Exit Function
                        If HK_IsValue(vB, kws, kwCount) And Not HK_LooksLabel(vB) Then HK_SearchTable = vB: Exit Function
                    End If
                    ' µÑ ´Ù ¶óº§Ã³·³ º¸ÀÌ¸é ¿À¸¥ÂÊ ¼¿ÀÌ¶óµµ Ã¤Åà (°ªÀÌ ¶óº§Ã³·³ »ý±ä µå¹® °æ¿ì)
                    If HK_IsValue(vR, kws, kwCount) Then HK_SearchTable = vR: Exit Function
                    ' °è¼Ó Ž»ö
                End If
            Next c
        Next r
    End With
End Function

' °°Àº Çà(r>0) ¶Ç´Â °°Àº ¿­(c>0)¿¡¼­ »ç¿ëÀÚ Å°¿öµå¿¡ ÇØ´çÇÏ´Â Ä­ ¼ö (skip À§Ä¡´Â Á¦¿Ü)
Private Function HK_CountKw(ByVal ti As Long, ByVal r As Long, ByVal c As Long, ByRef kws() As String, ByVal kwCount As Long, ByVal skip As Long) As Long
    ' 09-29: º´ÇÕ Ä­Àº ÇÑ ¹ø¸¸ ¼¾´Ù(°°Àº cid), skip Ä­(Å°¿öµå ÀÚ½Å)°ú °°Àº º´ÇÕ Ä­µµ Á¦¿Ü
    Dim i As Long, k As Long, s As String, n As Long, lim As Long, id As Long, lastId As Long, skipId As Long
    With tbls(ti)
        If r > 0 Then lim = .nCols: skipId = .cid(r, skip) Else lim = .nRows: skipId = .cid(skip, c)
        lastId = -1
        For i = 1 To lim
            If r > 0 Then id = .cid(r, i): s = .txt(r, i) Else id = .cid(i, c): s = .txt(i, c)
            If id <> skipId And id <> lastId Then
                lastId = id
                For k = 1 To kwCount
                    If hkFuzzy Then s = HK_FuzzyFix(s, kws(k))
                    If HK_IsKeywordCell(s, kws(k), HK_Norm(kws(k))) Then n = n + 1: Exit For
                Next k
            End If
        Next i
    End With
    HK_CountKw = n
End Function

' 09-29: ±ÛÀÌ »ç¿ëÀÚ Å°¿öµå Áß ÇϳªÀÇ ¶óº§ Ä­ÀÎÁö
Private Function HK_IsAnyKw(ByVal s As String, ByRef kws() As String, ByVal kwCount As Long) As Boolean
    Dim k As Long
    For k = 1 To kwCount
        If HK_IsKeywordCell(s, kws(k), HK_Norm(kws(k))) Then HK_IsAnyKw = True: Exit Function
    Next k
End Function

Private Function HK_SearchLine(ByVal li As Long, ByVal kw As String, ByRef kws() As String, ByVal kwCount As Long) As String
    Dim s As String, v As String, p As Long, nb As Long, nxt As Long
    s = lines(li)
    If hkFuzzy Then s = HK_FuzzyFix(s, kw)
    p = InStr(1, s, kw, vbTextCompare)
    If p = 0 Then Exit Function
    v = HK_AfterKeyword(s, kw)
    If HK_IsValue(v, kws, kwCount) Then HK_SearchLine = v: Exit Function
    If Len(HK_Norm(s)) = Len(HK_Norm(kw)) Then
        ' ÁÙ Àüü°¡ Å°¿öµå»ÓÀÌ¸é ´ÙÀ½ ¹®´Ü(ºñ¾î ÀÖÁö ¾ÊÀº °Í)
        For nb = 1 To blockCount
            If blocks(nb) = li Then
                For nxt = nb + 1 To blockCount
                    If blocks(nxt) > 0 Then
                        v = lines(blocks(nxt))
                        If Len(Trim$(v)) > 0 Then
                            If HK_IsValue(v, kws, kwCount) Then HK_SearchLine = v
                            Exit Function
                        End If
                    Else
                        Exit Function
                    End If
                Next nxt
                Exit Function
            End If
        Next nb
    End If
End Function

' Çì´õÇà ÆÇÁ¤: ±× ÇàÀÇ Ã¤¿öÁø ¼¿ÀÌ 2°³ ÀÌ»óÀÌ°í ¸ðµÎ ¼ýÀÚ ¾ø´Â ªÀº ¶óº§À̸ç, ¹Ù·Î ¾Æ·¡ Çà¿¡ °ªÀÌ ÀÖÀ½
Private Function HK_IsHeaderRow(ByVal ti As Long, ByVal r As Long) As Boolean
    Dim c As Long, s As String, filled As Long, below As Long, i As Long
    With tbls(ti)
        If r >= .nRows Then Exit Function
        For c = 1 To .nCols
            s = Trim$(.txt(r, c))
            If Len(s) > 0 Then
                filled = filled + 1
                If Len(s) > 12 Then Exit Function
                For i = 1 To Len(s)
                    If Mid$(s, i, 1) Like "#" Then Exit Function
                Next i
            End If
            If Len(Trim$(.txt(r + 1, c))) > 0 Then below = below + 1
        Next c
    End With
    HK_IsHeaderRow = (filled >= 2 And below >= 1)
End Function

Private Function HK_IsKeywordCell(ByVal cellText As String, ByVal kw As String, ByVal kn As String) As Boolean
    Dim cn As String
    cn = HK_Norm(cellText)
    If Len(cn) = 0 Then Exit Function
    If cn = kn Then HK_IsKeywordCell = True: Exit Function
    ' "¼º¸í(ÇѱÛ)" ó·³ Å°¿öµå·Î ½ÃÀÛÇÏ°í ª°Ô µ¡ºÙÀº ¶óº§, ¶Ç´Â "¼º¸í: È«±æµ¿" ÇüÅÂ
    If Left$(cn, Len(kn)) = kn Then
        If InStr(1, cellText, kw, vbTextCompare) > 0 Then HK_IsKeywordCell = True
    End If
End Function

Private Function HK_AfterKeyword(ByVal s As String, ByVal kw As String) As String
    Dim p As Long, v As String, i As Long, cH As String
    p = InStr(1, s, kw, vbTextCompare)
    If p = 0 Then Exit Function
    v = Mid$(s, p + Len(kw))
    ' [¼öÁ¤] Å°¿öµå ¹Ù·Î µÚ¿¡ ±ÛÀÚ/¼ýÀÚ°¡ À̾îÁö¸é("Çб³¸í", "¼º¸í¶õ") ´õ ±ä ¶óº§À̹ǷΠ°°Àº ¼¿ °ªÀ¸·Î º¸Áö ¾Ê´Â´Ù
    If Len(v) > 0 Then
        If Left$(v, 1) Like "[°¡-ÆRA-Za-z0-9]" Then Exit Function
    End If
    ' °ýÈ£ º¸Ãæ¾î Á¦°Å: "(ÇѱÛ)" µî
    If Left$(LTrim$(v), 1) = "(" And InStr(v, ")") > 0 Then v = Mid$(v, InStr(v, ")") + 1)
    ' ¾ÕÂÊ ±¸ºÐ ±âÈ£ Á¦°Å
    For i = 1 To Len(v)
        cH = Mid$(v, i, 1)
        If InStr(" :£º=-¡¤_|/,¡¢£¬" & ChrW(8226) & ChrW(8211) & ChrW(8212) & vbTab & Chr(7), cH) = 0 Then Exit For
    Next i
    v = Mid$(v, i)
    HK_AfterKeyword = Trim$(v)
End Function

' v ÀÇ p À§Ä¡¿¡ ÀÖ´Â Å°¿öµå°¡ ¶óº§·Î ¾²ÀÎ °ÍÀÎÁö: ¾Õ ±ÛÀÚ°¡ °ø¹é/±¸ºÐÀÚ(¶Ç´Â ½ÃÀÛ)ÀÌ°í µÚ ±ÛÀÚ°¡ ±¸ºÐÀÚ(:, °ø¹é µî)À̰ųª ³¡
Private Function HK_IsLabelAt(ByVal v As String, ByVal p As Long, ByVal kwLen As Long) As Boolean
    Dim prevCh As String, nextCh As String
    If p > 1 Then prevCh = Mid$(v, p - 1, 1)
    If p + kwLen <= Len(v) Then nextCh = Mid$(v, p + kwLen, 1)
    If Len(prevCh) > 0 Then
        If InStr(" ,;|/()[]" & vbTab, prevCh) = 0 Then Exit Function
    End If
    If Len(nextCh) = 0 Then HK_IsLabelAt = True: Exit Function
    HK_IsLabelAt = (InStr(" :£º=-_|/(" & vbTab, nextCh) > 0)
End Function

' Ç׸ñ ¶óº§Ã³·³ º¸À̴ ªÀº ¹®±¸ (°ªÀÌ ¾Æ´Ï¶ó ´ÙÀ½ Ç׸ñ¸í): ¼ýÀÚ ¾øÀÌ 6ÀÚ ÀÌÇÏÀÌ°í ¸í/¹øÈ£/ÀÏÀÚ/ÁÖ¼Ò µîÀ¸·Î ³¡³²
Private Function HK_LooksLabel(ByVal v As String) As Boolean
    Dim n As String, i As Long, tails As Variant, T As Variant
    ' 09-29: °¡¸² Ç¥½Ã(* ¡Û ¡Ü)°¡ µç ±ÛÀº °¡·ÁÁø °ªÀÌÁö ¶óº§ÀÌ ¾Æ´Ô
    If InStr(v, "*") > 0 Or InStr(v, ChrW(9675)) > 0 Or InStr(v, ChrW(9679)) > 0 Then Exit Function
    n = HK_Norm(v)
    If Len(n) = 0 Or Len(n) > 6 Then Exit Function
    For i = 1 To Len(n)
        If Mid$(n, i, 1) Like "#" Then Exit Function
    Next i
    tails = Array("¸í", "¹øÈ£", "ÀÏÀÚ", "ÀϽÃ", "ÁÖ¼Ò", "¼º¸í", "¿¬¶ôó", "À̸ÞÀÏ", "ºñ°í", "±¸ºÐ", "¼ºº°", "Á÷À§", "¼Ò¼Ó", "Çгâ", "Çб³", "»ý³â¿ùÀÏ", "ÀºÇà", "¿¹±ÝÁÖ", "±Ý¾×", "°èÁÂ", "ÀüÈ­", "ÈÞ´ëÆù", "¸ÞÀÏ", "email", "ºÎ¼­", "Á÷±Þ", "°ú¸ñ", "±â°ü", "¾÷¹«", "ÇзÂ", "°æ·Â", "Á¡¼ö", "ÇÐÀ§")
    For Each T In tails
        If Right$(n, Len(T)) = T Then HK_LooksLabel = True: Exit Function
    Next T
End Function

Private Function HK_IsValue(ByVal v As String, ByRef kws() As String, ByVal kwCount As Long) As Boolean
    Dim i As Long, vn As String
    vn = HK_Norm(v)
    If Len(vn) = 0 Then Exit Function
    For i = 1 To kwCount
        If vn = HK_Norm(kws(i)) Then Exit Function
        If hkFuzzy Then
            If HK_Norm(HK_FuzzyFix(v, kws(i))) = HK_Norm(kws(i)) Then Exit Function
        End If
    Next i
    HK_IsValue = True
End Function

Private Function HK_Norm(ByVal s As String) As String
    Dim i As Long, cH As String, o As String
    For i = 1 To Len(s)
        cH = Mid$(s, i, 1)
        If InStr(" " & vbTab & vbCr & vbLf & Chr(7) & ":£º*¡Ø¢º¡¤-_|/()£¨£©[]¡²¡³" & ChrW(8211) & ChrW(8212) & ChrW(9702), cH) = 0 Then o = o & cH
    Next i
    HK_Norm = LCase$(o)
End Function

Private Function HK_Clean(ByVal v As String, ByVal kw As String, ByRef kws() As String, ByVal kwCount As Long) As String
    Dim i As Long, p As Long, cut As Long
    v = Replace(Replace(Replace(v, vbCr, " "), vbLf, " "), vbTab, " ")
    v = Replace(v, Chr(7), "")
    Do While InStr(v, "  ") > 0
        v = Replace(v, "  ", " ")
    Loop
    v = Trim$(v)
    ' °ª µÚ¿¡ ´Ù¸¥ Å°¿öµå°¡ À̾îÁö¸é ±× ¾Õ¿¡¼­ ÀÚ¸£±â ("(ÁÖ)°¡³ª´Ù ´ëÇ¥: È«±æµ¿")
    cut = 0
    For i = 1 To kwCount
        If StrComp(kws(i), kw, vbTextCompare) <> 0 Then
            p = InStr(2, v, kws(i), vbTextCompare)
            Do While p > 0
                If HK_IsLabelAt(v, p, Len(kws(i))) Then
                    If cut = 0 Or p < cut Then cut = p
                    Exit Do
                End If
                p = InStr(p + 1, v, kws(i), vbTextCompare)
            Loop
        End If
    Next i
    If cut > 0 Then v = Trim$(Left$(v, cut - 1))
    Do While Len(v) > 0
        If InStr(",;|:-¡¤", Right$(v, 1)) > 0 Then v = Left$(v, Len(v) - 1) Else Exit Do
    Loop
    If Len(v) > MAX_VALUE_LEN Then v = Left$(v, MAX_VALUE_LEN) & "¡¦"
    HK_Clean = Trim$(v)
End Function

' =====================================================================================
'  ¹®¼­ Àбâ : HWPX
' =====================================================================================
Private Sub HK_Reset()
    tblCount = 0: lineCount = 0: blockCount = 0: cellSeq = 0: hkFuzzy = False
    ReDim tbls(1 To 64): ReDim lines(1 To 512): ReDim linePage(1 To 512): ReDim blocks(1 To 576)
End Sub

Private Sub HK_AddLine(ByVal s As String, ByVal page As Long)
    s = Trim$(s)
    If Len(s) = 0 Then Exit Sub
    lineCount = lineCount + 1
    If lineCount > UBound(lines) Then
        ReDim Preserve lines(1 To UBound(lines) * 2)
        ReDim Preserve linePage(1 To UBound(lines))
    End If
    lines(lineCount) = s: linePage(lineCount) = page
    HK_AddBlock lineCount
End Sub

Private Sub HK_AddBlock(ByVal v As Long)
    blockCount = blockCount + 1
    If blockCount > UBound(blocks) Then ReDim Preserve blocks(1 To UBound(blocks) * 2)
    blocks(blockCount) = v
End Sub

Private Function HK_NewTable(ByVal nRows As Long, ByVal nCols As Long, ByVal page As Long) As Long
    tblCount = tblCount + 1
    If tblCount > UBound(tbls) Then ReDim Preserve tbls(1 To UBound(tbls) * 2)
    With tbls(tblCount)
        .nRows = nRows: .nCols = nCols: .page = page
        ReDim .txt(1 To nRows, 1 To nCols)
        ReDim .cid(1 To nRows, 1 To nCols)
    End With
    HK_AddBlock -tblCount
    HK_NewTable = tblCount
End Function

Private Function HK_LoadHwpx(ByVal path As String) As Boolean
    Dim fso As Object, tmp As String, secFiles As Collection, i As Long, xml As Object
    On Error GoTo Fail
    Set fso = CreateObject("Scripting.FileSystemObject")
    HK_Reset
    tmp = HK_Unzip(path, fso)
    If Len(tmp) = 0 Then Exit Function
    Set secFiles = New Collection
    For i = 0 To 30
        If fso.FileExists(fso.BuildPath(tmp, "Contents\section" & i & ".xml")) Then
            secFiles.Add fso.BuildPath(tmp, "Contents\section" & i & ".xml")
        Else
            If i > 0 Then Exit For
        End If
    Next i
    For i = 1 To secFiles.Count
        Set xml = CreateObject("MSXML2.DOMDocument.6.0")
        xml.async = False: xml.validateOnParse = False
        If xml.Load(secFiles(i)) Then HK_WalkParent xml.documentElement, 0
    Next i
    HK_LoadHwpx = (blockCount > 0)
Cleanup:
    On Error Resume Next
    If Len(tmp) > 0 Then fso.DeleteFolder tmp, True
    Exit Function
Fail:
    Resume Cleanup
End Function

' ºÎ¸ð ³ëµå ¾Æ·¡ÀÇ ¹®´Ü(hp:p)µéÀ» ¼ø¼­´ë·Î ó¸®
Private Sub HK_WalkParent(ByVal parent As Object, ByVal page As Long)
    Dim node As Object
    For Each node In parent.childNodes
        If node.nodeName = "hp:p" Then
            HK_WalkPara node, page
        ElseIf node.nodeType = 1 Then
            HK_WalkParent node, page
        End If
    Next node
End Sub

' ¹®´Ü: ÅؽºÆ®´Â ÇÑ ÁÙ·Î, Ç¥´Â Ç¥ ºí·ÏÀ¸·Î (¹®¼­ ¼ø¼­ À¯Áö)
Private Sub HK_WalkPara(ByVal pNode As Object, ByVal page As Long)
    Dim run As Object, child As Object, s As String
    For Each run In pNode.childNodes
        If run.nodeName = "hp:run" Then
            For Each child In run.childNodes
                If child.nodeName = "hp:t" Then
                    s = s & child.text
                ElseIf child.nodeName = "hp:tbl" Then
                    If Len(Trim$(s)) > 0 Then HK_AddLine s, page: s = ""
                    HK_ParseTable child, page
                ElseIf child.nodeType = 1 Then
                    ' ±Û»óÀÚ µî ´Ù¸¥ °³Ã¼ ¾ÈÀÇ ¹®´Ü
                    If Len(Trim$(s)) > 0 Then HK_AddLine s, page: s = ""
                    HK_WalkParent child, page
                End If
            Next child
        End If
    Next run
    If Len(Trim$(s)) > 0 Then HK_AddLine s, page
End Sub

Private Sub HK_ParseTable(ByVal tblNode As Object, ByVal page As Long)
    Dim nRows As Long, nCols As Long, ti As Long, tr As Object, tc As Object, node As Object
    Dim r As Long, c As Long, rs As Long, cs As Long, i As Long, j As Long, txt As String, curRow As Long
    nRows = val(tblNode.getAttribute("rowCnt")): nCols = val(tblNode.getAttribute("colCnt"))
    If nRows <= 0 Or nCols <= 0 Then Exit Sub
    ti = HK_NewTable(nRows, nCols, page)
    curRow = 0
    For Each tr In tblNode.childNodes
        If tr.nodeName = "hp:tr" Then
            curRow = curRow + 1
            For Each tc In tr.childNodes
                If tc.nodeName = "hp:tc" Then
                    r = curRow: c = 0: rs = 1: cs = 1: txt = ""
                    For Each node In tc.childNodes
                        Select Case node.nodeName
                            Case "hp:cellAddr"
                                r = val(node.getAttribute("rowAddr")) + 1
                                c = val(node.getAttribute("colAddr")) + 1
                            Case "hp:cellSpan"
                                cs = val(node.getAttribute("colSpan")): rs = val(node.getAttribute("rowSpan"))
                                If cs < 1 Then cs = 1
                                If rs < 1 Then rs = 1
                            Case "hp:subList"
                                txt = HK_CellText(node, page)
                        End Select
                    Next node
                    If c = 0 Then c = 1
                    cellSeq = cellSeq + 1
                    For i = r To r + rs - 1
                        For j = c To c + cs - 1
                            If i >= 1 And i <= nRows And j >= 1 And j <= nCols Then
                                tbls(ti).txt(i, j) = txt
                                tbls(ti).cid(i, j) = cellSeq
                            End If
                        Next j
                    Next i
                End If
            Next tc
        End If
    Next tr
End Sub

' ¼¿ ÅؽºÆ®: ¼¿ ¾È ¹®´ÜµéÀ» °ø¹éÀ¸·Î ÀÌ¾î ºÙÀÓ. ¼¿ ¾ÈÀÇ Ç¥(Áßø)´Â º°µµ Ç¥ ºí·ÏÀ¸·Î µî·Ï
Private Function HK_CellText(ByVal subList As Object, ByVal page As Long) As String
    Dim p As Object, run As Object, child As Object, s As String
    For Each p In subList.childNodes
        If p.nodeName = "hp:p" Then
            For Each run In p.childNodes
                If run.nodeName = "hp:run" Then
                    For Each child In run.childNodes
                        If child.nodeName = "hp:t" Then
                            s = s & child.text
                        ElseIf child.nodeName = "hp:tbl" Then
                            HK_ParseTable child, page
                        End If
                    Next child
                End If
            Next run
            s = s & " "
        End If
    Next p
    HK_CellText = Trim$(s)
End Function

Private Function HK_Unzip(ByVal path As String, ByVal fso As Object) As String
    Dim shellApp As Object, tmpRoot As String, stamp As String, tmpFolder As String, zipPath As String
    Dim nsZip As Object, nsDest As Object, T As Single
    On Error GoTo Fail
    Set shellApp = CreateObject("Shell.Application")
    tmpRoot = Environ$("TEMP")
    stamp = Format$(Now, "yyyymmdd_hhnnss") & "_" & CStr(Int(Rnd() * 100000))
    tmpFolder = fso.BuildPath(tmpRoot, "hk_" & stamp)
    zipPath = fso.BuildPath(tmpRoot, "hk_" & stamp & ".zip")
    fso.CopyFile path, zipPath, True
    ' PowerShell Expand-Archive (µ¿±â ½ÇÇà) - Shell.Application CopyHere´Â ȯ°æ¿¡ µû¶ó ¾Æ¹«°Íµµ Ç®Áö ¾Ê´Â °æ¿ì°¡ ÀÖÀ½
    Set shellApp = CreateObject("WScript.Shell")
    shellApp.run "powershell.exe -NoProfile -ExecutionPolicy Bypass -Command ""Expand-Archive -LiteralPath '" & zipPath & "' -DestinationPath '" & tmpFolder & "' -Force""", 0, True
    If Not fso.FileExists(fso.BuildPath(tmpFolder, "Contents\section0.xml")) Then
        ' ¿¹ºñ: Shell.Application ¹æ½Ä
        Set nsZip = CreateObject("Shell.Application").Namespace(CVar(zipPath))
        If Not fso.FolderExists(tmpFolder) Then fso.CreateFolder tmpFolder
        Set nsDest = CreateObject("Shell.Application").Namespace(CVar(tmpFolder))
        If nsZip Is Nothing Or nsDest Is Nothing Then GoTo Fail
        nsDest.CopyHere nsZip.items, 4 + 16 + 1024
        T = Timer
        Do While Timer - T < 20
            DoEvents
            If fso.FileExists(fso.BuildPath(tmpFolder, "Contents\section0.xml")) Then Exit Do
        Loop
    End If
    If Not fso.FileExists(fso.BuildPath(tmpFolder, "Contents\section0.xml")) Then GoTo Fail
    On Error Resume Next
    fso.DeleteFile zipPath, True
    HK_Unzip = tmpFolder
    Exit Function
Fail:
    On Error Resume Next
    If Len(zipPath) > 0 Then fso.DeleteFile zipPath, True
    HK_Unzip = ""
End Function

' =====================================================================================
'  ¹®¼­ Àбâ : HWP (Çѱ۷Π¿­¾î hwpx Àӽà º¯È¯)
' =====================================================================================
Private Function HK_CreateHwp() As Object
    Dim H As Object
    On Error Resume Next
    Set H = CreateObject("HWPFrame.HwpObject")
    If H Is Nothing Then Set H = CreateObject("Hancom.HwpObject")
    If Not H Is Nothing Then
        H.RegisterModule "FilePathCheckDLL", "FilePathCheckerModule"
        H.XHwpWindows.item(0).Visible = False
    End If
    Set HK_CreateHwp = H
End Function

Private Function HK_LoadHwpViaHwpx(ByVal path As String, ByVal hwp As Object, ByVal fso As Object) As Boolean
    Dim tmpX As String, ok As Boolean
    On Error Resume Next
    Err.Clear
    ' [ÇÙ½É ¼öÁ¤] ÇÑ±Û COM ÀÇ Open/SaveAs ´Â Boolean 1 À» µ¹·ÁÁֹǷΠNot ok °¡ True °¡ µÇ´Â VBA ÇÔÁ¤ ¡æ (<> 0) À¸·Î Á¤±ÔÈ­
    ok = (hwp.Open(path, "HWP", "forceopen:true") <> 0)
    hkNote = "open=" & ok
    If Err.Number <> 0 Then hkNote = hkNote & " openerr=" & Err.Description: Err.Clear
    If Not ok Then
        HK_LoadHwpViaHwpx = HK_LoadHwpText(hwp)
        hkNote = hkNote & " text=" & HK_LoadHwpViaHwpx
        Exit Function
    End If
    tmpX = fso.BuildPath(Environ$("TEMP"), "hk_" & Format$(Now, "hhnnss") & "_" & Int(Rnd() * 10000) & ".hwpx")
    Err.Clear
    ok = (hwp.SaveAs(tmpX, "HWPX", "") <> 0)
    hkNote = hkNote & " saveas=" & ok & "/" & fso.FileExists(tmpX)
    If Err.Number <> 0 Then hkNote = hkNote & " saveerr=" & Err.Description: Err.Clear
    If ok And fso.FileExists(tmpX) Then
        HK_LoadHwpViaHwpx = HK_LoadHwpx(tmpX)
        hkNote = hkNote & " hwpx=" & HK_LoadHwpViaHwpx
        If Err.Number <> 0 Then hkNote = hkNote & " parseerr=" & Err.Description: Err.Clear
        fso.DeleteFile tmpX, True
    End If
    Err.Clear
    ' ¿øº» ¹®¼­¸¦ ´Ù½Ã ¿­¾î µÐ´Ù(ÆäÀÌÁö ã±â¿ë). SaveAs µÚ¿¡´Â ÇöÀç ¹®¼­°¡ hwpx »çº»À̹ǷΠÀç¿ÀÇÂ
    hwp.Open path, "HWP", "forceopen:true"
    If Not HK_LoadHwpViaHwpx Then
        HK_LoadHwpViaHwpx = HK_LoadHwpText(hwp)
        hkNote = hkNote & " text=" & HK_LoadHwpViaHwpx
    End If
End Function

' ¿¹ºñ: ÇÑ±Û ÅؽºÆ® ÃßÃâ(Ç¥ ±¸Á¶ ¾øÀ½). Ç¥ ¼¿ÀÌ ÇÑ ÁÙ¾¿ ³ª¿À¹Ç·Î "Å°¿öµå ´ÙÀ½ ÁÙ" ±ÔÄ¢À¸·Î ÆǺ°
Private Function HK_LoadHwpText(ByVal hwp As Object) As Boolean
    Dim T As String, ln As Variant
    On Error Resume Next
    HK_Reset
    T = hwp.GetTextFile("UNICODE", "")
    If Len(T) = 0 Then T = hwp.GetTextFile("TEXT", "")
    If Len(T) = 0 Then Exit Function
    T = Replace(Replace(T, vbCr, vbLf), Chr(7), vbLf)
    For Each ln In Split(T, vbLf)
        HK_AddLine CStr(ln), 0
    Next ln
    HK_LoadHwpText = (lineCount > 0)
End Function

Private Sub HK_HwpClose(ByVal hwp As Object)
    On Error Resume Next
    hwp.HAction.run "FileClose"
End Sub

' ÇöÀç ¿­¸° ÇÑ±Û ¹®¼­¿¡¼­ Å°¿öµå°¡ óÀ½ ³ª¿À´Â ÂÊ ¹øÈ£ (½ÇÆÐ ½Ã 0)
Private Function HK_HwpPageOf(ByVal hwp As Object, ByVal kw As String) As Long
    Dim act As Object, frSet As Object, found As Boolean
    Dim seccnt As Variant, secno As Variant, prnpageno As Variant, colno As Variant
    Dim ln As Variant, pos As Variant, over As Variant, ctrlname As Variant
    On Error GoTo Fail
    hwp.HAction.run "MoveDocBegin"
    Set act = hwp.HAction
    Set frSet = hwp.HParameterSet.HFindReplace
    act.GetDefault "RepeatFind", frSet.HSet
    frSet.FindString = kw
    frSet.IgnoreMessage = 1
    frSet.Direction = hwp.FindDir("Forward")
    frSet.MatchCase = 0
    frSet.FindType = 1
    found = act.Execute("RepeatFind", frSet.HSet)
    If Not found Then Exit Function
    hwp.KeyIndicator seccnt, secno, prnpageno, colno, ln, pos, over, ctrlname
    HK_HwpPageOf = CLng(prnpageno)
    Exit Function
Fail:
    HK_HwpPageOf = 0
End Function

' =====================================================================================
'  ¹®¼­ Àбâ : PDF (Word·Î ¿­¾î Ç¥/¹®´Ü Àбâ)
' =====================================================================================
Private Function HK_CreateWord() As Object
    Dim W As Object
    On Error Resume Next
    Set W = CreateObject("Word.Application")
    If Not W Is Nothing Then
        W.Visible = False
        W.DisplayAlerts = 0
    End If
    Set HK_CreateWord = W
End Function

Private Function HK_LoadPdfViaWord(ByVal path As String, ByVal wdApp As Object) As Boolean
    Dim doc As Object, para As Object, tbl As Object, ti As Long, r As Long, c As Long
    Dim Done As Object, key As String, txt As String, page As Long, cel As Object
    On Error GoTo Fail
    HK_Reset
    Set doc = wdApp.Documents.Open(path, False, True, False)
    Set Done = CreateObject("Scripting.Dictionary")
    For Each para In doc.Paragraphs
        page = para.Range.Information(3)          ' wdActiveEndPageNumber
        If para.Range.Information(12) Then          ' wdWithInTable
            Set tbl = para.Range.Tables(1)
            key = CStr(tbl.Range.Start)
            If Not Done.Exists(key) Then
                Done.Add key, 1
                ti = HK_NewTable(tbl.rows.Count, tbl.Columns.Count, page)
                On Error Resume Next
                For Each cel In tbl.Range.cells
                    r = cel.RowIndex: c = cel.ColumnIndex
                    txt = cel.Range.text
                    If Len(txt) >= 2 Then txt = Left$(txt, Len(txt) - 2)   ' ¼¿ ³¡ Ç¥½Ä Á¦°Å
                    If r >= 1 And r <= tbls(ti).nRows And c >= 1 And c <= tbls(ti).nCols Then
                        cellSeq = cellSeq + 1
                        tbls(ti).txt(r, c) = Trim$(Replace(txt, vbCr, " "))
                        tbls(ti).cid(r, c) = cellSeq
                    End If
                Next cel
                On Error GoTo Fail
            End If
        Else
            HK_AddLine para.Range.text, page
        End If
    Next para
    doc.Close False
    HK_LoadPdfViaWord = (blockCount > 0)
    Exit Function
Fail:
    On Error Resume Next
    If Not doc Is Nothing Then doc.Close False
    HK_LoadPdfViaWord = False
End Function

' =====================================================================================
'  ¹®¼­ Àбâ : À̹ÌÁö (Windows ³»Àå OCR, Windows 10 ÀÌ»ó / Office ¹öÀü ¹«°ü)
'   [v2.7] OCR ´Ü¾îÀÇ ÁÂÇ¥(BoundingRect)¸¦ ¹Þ¾Æ Ç¥ ±¸Á¶¸¦ Èä³» ³½´Ù:
'     ¨ç ´Ü¾î¸¦ ¼¼·Î À§Ä¡·Î ÇàÀ¸·Î ¹­°í ¨è Çà ¾È¿¡¼­ ±ÛÀÚ ÆøÀÇ 2¹è°¡ ³Ñ´Â ºóÆ´À» Ä­ °æ°è·Î »ï¾Æ Ä­À» ³ª´« µÚ
'     ¨é ÇÑ Ç¥(Çà ¡¿ Ä­)·Î µî·Ï ¡æ hwpx Ç¥¿Í °°Àº ±ÔÄ¢(°°Àº Ä­ "Å°¿öµå: °ª" ¡æ ¿À¸¥ÂÊ Ä­ ¡æ ¾Æ·¡ Ä­)À¸·Î °ªÀ» ã´Â´Ù.
'     ÁÂÇ¥°¡ ¾øÀ¸¸é(±¸Çü °á°ú) ÁÙ ´ÜÀ§ ±ÔÄ¢À¸·Î ó¸®
' =====================================================================================
Private Function HK_LoadImageViaOcr(ByVal path As String, ByVal fso As Object) As Boolean
    Dim tmp As String, ps1 As String, outTxt As String, Sh As Object, cmd As Object
    Dim T As Single, txt As String, ln As Variant, parts() As String
    Dim wt() As String, wx() As Single, wy() As Single, ww() As Single, wh() As Single, nW As Long, hasWords As Boolean
    On Error GoTo Fail
    HK_Reset
    hkFuzzy = True
    tmp = Environ$("TEMP")
    ps1 = fso.BuildPath(tmp, "busan_winocr2.ps1")
    outTxt = fso.BuildPath(tmp, "busan_winocr_" & Format$(Now, "hhnnss") & Int(Rnd() * 1000) & ".txt")
    HK_WriteUtf8File ps1, HK_OcrScript()
    Set Sh = CreateObject("WScript.Shell")
    Set cmd = Sh.Exec("powershell.exe -NoProfile -ExecutionPolicy Bypass -File """ & ps1 & """ -path """ & path & """ -out """ & outTxt & """")
    T = Timer
    Do While cmd.status = 0
        DoEvents
        If Timer - T > 60 Then Exit Do
    Loop
    If Not fso.FileExists(outTxt) Then Exit Function
    txt = HK_ReadUtf8File(outTxt)
    fso.DeleteFile outTxt, True
    If Left$(txt, 5) = "ERROR" Then hkNote = Mid$(txt, 1, 80): Exit Function
    ReDim wt(1 To 1024): ReDim wx(1 To 1024): ReDim wy(1 To 1024): ReDim ww(1 To 1024): ReDim wh(1 To 1024)
    For Each ln In Split(Replace(txt, vbCr, ""), vbLf)
        If Left$(CStr(ln), 2) = "S" & vbTab Then
            ' »õ ¹èÀ² ±¸°£: ¾Õ ±¸°£ÀÇ ´Ü¾î·Î Ç¥ µî·Ï
            If nW > 0 Then HK_BuildOcrTable wt, wx, wy, ww, wh, nW
            nW = 0: hasWords = True
        ElseIf Left$(CStr(ln), 2) = "W" & vbTab Then
            parts = Split(CStr(ln), vbTab)
            If UBound(parts) >= 6 Then
                nW = nW + 1
                If nW > UBound(wt) Then
                    ReDim Preserve wt(1 To nW * 2): ReDim Preserve wx(1 To nW * 2): ReDim Preserve wy(1 To nW * 2)
                    ReDim Preserve ww(1 To nW * 2): ReDim Preserve wh(1 To nW * 2)
                End If
                wt(nW) = parts(2): wx(nW) = val(parts(3)): wy(nW) = val(parts(4)): ww(nW) = val(parts(5)): wh(nW) = val(parts(6))
                hasWords = True
            End If
        ElseIf Left$(CStr(ln), 2) = "L" & vbTab Then
            ' ÁÙ ±ÛÀڴ ǥ µî·Ï ¶§ Çà ´ÜÀ§·Î ³ÖÀ¸¹Ç·Î ¿©±â¼­´Â »ý·«
        ElseIf Not hasWords Then
            HK_AddLine CStr(ln), 1
        End If
    Next ln
    If hasWords Then HK_BuildOcrTable wt, wx, wy, ww, wh, nW
    HK_LoadImageViaOcr = (lineCount > 0 Or tblCount > 0)
    Exit Function
Fail:
    hkNote = "OCR ¿À·ù: " & Err.Description
    HK_LoadImageViaOcr = False
End Function

' ´Ü¾î ÁÂÇ¥ ¡æ Çà/Ä­ Ç¥. Ä­ ¼ø¼­(¿ÞÂʺÎÅÍ 1,2,3¡¦)¸¦ ¿­ ¹øÈ£·Î ½á¼­ "¿À¸¥ÂÊ Ä­"ÀÌ Ç×»ó °°Àº ÇàÀÇ ´ÙÀ½ Ä­ÀÌ µÇ°Ô ÇÑ´Ù
Private Sub HK_BuildOcrTable(ByRef wt() As String, ByRef wx() As Single, ByRef wy() As Single, ByRef ww() As Single, ByRef wh() As Single, ByVal nW As Long)
    Dim idx() As Long, i As Long, j As Long, T As Long, cy() As Single, sumH As Single, avgH As Single
    Dim rowOf() As Long, nRows As Long, rowCy As Single, rowN As Long, units As Long, sumW As Single, avgCharW As Single, gapThr As Single
    Dim rowStart() As Long, rowEnd() As Long, r As Long, cellTxt As String, prevRight As Single, nCells As Long, maxCells As Long
    Dim ti As Long, rowCells() As String, rowCellN() As Long, k As Long, rowText As String
    Dim rowCellX() As Single, rowCellCol() As Long, ax() As Single, ar() As Long, ac() As Long, nAll As Long, aIdx() As Long, nColX As Long, lastX As Single, colTol As Single
    If nW = 0 Then Exit Sub
    ' Æò±Õ ±ÛÀÚ Æø(ÇÑ±Û 1ÀÚ ±âÁØ): ´Ü¾î Æø / ±ÛÀÚ ´ÜÀ§ ¼ö
    For i = 1 To nW
        units = HK_TextUnits(wt(i))
        If units > 0 Then sumW = sumW + ww(i) / (units / 2)
        sumH = sumH + wh(i)
    Next i
    avgH = sumH / nW
    ' ±ÛÀÚ ÆøÀº ´Ü¾î ³ôÀÌ·Î ÃßÁ¤(ÇÑ±Û ÇÑ ÀÚ = ´ë·« Á¤»ç°¢Çü). ´Ü¾î Æø/±ÛÀÚ¼ö Æò±ÕÀº "°ª1" °°Àº ªÀº ´Ü¾î¿¡ ¿Ö°îµÊ
    avgCharW = avgH * 0.9
    If avgCharW < 4 Then avgCharW = 4
    gapThr = avgCharW * 2.2
    ' ¼¼·Î Áß½ÉÀ¸·Î Á¤·Ä
    ReDim idx(1 To nW): ReDim cy(1 To nW)
    For i = 1 To nW
        idx(i) = i: cy(i) = wy(i) + wh(i) / 2
    Next i
    For i = 1 To nW - 1
        For j = i + 1 To nW
            If cy(idx(j)) < cy(idx(i)) Then T = idx(i): idx(i) = idx(j): idx(j) = T
        Next j
    Next i
    ' ÇàÀ¸·Î ¹­±â (Á᫐ Â÷ÀÌ°¡ ±ÛÀÚ ³ôÀÌÀÇ 0.6¹è À̳»)
    ReDim rowOf(1 To nW): ReDim rowStart(1 To nW): ReDim rowEnd(1 To nW)
    nRows = 0
    For i = 1 To nW
        If nRows = 0 Then
            nRows = 1: rowCy = cy(idx(i)): rowN = 1: rowStart(1) = i
        ElseIf Abs(cy(idx(i)) - rowCy) <= avgH * 0.6 Then
            rowCy = (rowCy * rowN + cy(idx(i))) / (rowN + 1): rowN = rowN + 1
        Else
            rowEnd(nRows) = i - 1
            nRows = nRows + 1: rowCy = cy(idx(i)): rowN = 1: rowStart(nRows) = i
        End If
        rowOf(idx(i)) = nRows
    Next i
    rowEnd(nRows) = nW
    ' Çà ¾È¿¡¼­ °¡·Î·Î Á¤·ÄÇÑ µÚ ºóÆ´À¸·Î Ä­ ³ª´©±â
    ReDim rowCells(1 To nRows, 1 To 64): ReDim rowCellN(1 To nRows): ReDim rowCellX(1 To nRows, 1 To 64): ReDim rowCellCol(1 To nRows, 1 To 64)
    For r = 1 To nRows
        For i = rowStart(r) To rowEnd(r) - 1
            For j = i + 1 To rowEnd(r)
                If wx(idx(j)) < wx(idx(i)) Then T = idx(i): idx(i) = idx(j): idx(j) = T
            Next j
        Next i
        nCells = 0: cellTxt = "": prevRight = -1
        For i = rowStart(r) To rowEnd(r)
            k = idx(i)
            If prevRight >= 0 And wx(k) - prevRight > gapThr And Not (Right$(cellTxt, 1) = "-" Or Left$(wt(k), 1) = "-") Then
                nCells = nCells + 1
                If nCells <= 64 Then rowCells(r, nCells) = Trim$(cellTxt)
                cellTxt = ""
            End If
            If Len(cellTxt) = 0 And nCells + 1 <= 64 Then rowCellX(r, nCells + 1) = wx(k)   ' Ä­ÀÇ ¿ÞÂÊ x
            cellTxt = cellTxt & IIf(Len(cellTxt) > 0, " ", "") & wt(k)
            If wx(k) + ww(k) > prevRight Then prevRight = wx(k) + ww(k)
        Next i
        nCells = nCells + 1
        If nCells <= 64 Then rowCells(r, nCells) = Trim$(cellTxt)
        If nCells > 64 Then nCells = 64
        rowCellN(r) = nCells
        If nCells > maxCells Then maxCells = nCells
    Next r
    ' ¿­ ¹øÈ£: ¸ðµç Ä­ÀÇ ¿ÞÂÊ x ¸¦ ¸ð¾Æ °¡±î¿î °Í³¢¸® ¹­´Â´Ù(°°Àº ¿­ÀÇ Ä­Àº x °¡ ºñ½ÁÇÔ) ¡æ OCR ÀÌ ÇÑ Ä­À» ³õÃĵµ ¾Æ·¡ Ä­ÀÌ ¾î±ß³ªÁö ¾ÊÀ½
    nAll = 0
    For r = 1 To nRows
        nAll = nAll + rowCellN(r)
    Next r
    ReDim ax(1 To nAll): ReDim ar(1 To nAll): ReDim ac(1 To nAll): ReDim aIdx(1 To nAll)
    i = 0
    For r = 1 To nRows
        For k = 1 To rowCellN(r)
            i = i + 1: ax(i) = rowCellX(r, k): ar(i) = r: ac(i) = k: aIdx(i) = i
        Next k
    Next r
    For i = 1 To nAll - 1
        For j = i + 1 To nAll
            If ax(aIdx(j)) < ax(aIdx(i)) Then T = aIdx(i): aIdx(i) = aIdx(j): aIdx(j) = T
        Next j
    Next i
    colTol = avgCharW * 1.5
    nColX = 0: lastX = -1000000000#
    For i = 1 To nAll
        k = aIdx(i)
        If ax(k) - lastX > colTol Then nColX = nColX + 1
        rowCellCol(ar(k), ac(k)) = nColX
        lastX = ax(k)
    Next i
    If nColX < 1 Then nColX = 1
    ' Ç¥ µî·Ï + Çà ±ÛÀÚ¸¦ Áٷεµ µî·Ï(¿¹ºñ ±ÔÄ¢¿ë)
    ti = HK_NewTable(nRows, nColX, 1)
    For r = 1 To nRows
        rowText = ""
        For k = 1 To rowCellN(r)
            j = rowCellCol(r, k)
            If j < 1 Then j = 1
            cellSeq = cellSeq + 1
            If Len(tbls(ti).txt(r, j)) > 0 Then
                tbls(ti).txt(r, j) = tbls(ti).txt(r, j) & " " & rowCells(r, k)
            Else
                tbls(ti).txt(r, j) = rowCells(r, k)
                tbls(ti).cid(r, j) = cellSeq
            End If
            rowText = rowText & IIf(Len(rowText) > 0, "  ", "") & rowCells(r, k)
        Next k
        HK_AddLine rowText, 1
    Next r
    hkNote = hkNote & IIf(Len(hkNote) > 0, " ", "OCR ") & nRows & "Çà/" & nColX & "Ä­"
End Sub

' ±ÛÀÚ ´ÜÀ§ ¼ö: Çѱۡ¤ÇÑÀÚ µî Àü°¢ 2, ±× ¿Ü 1
Private Function HK_TextUnits(ByVal s As String) As Long
    Dim i As Long, n As Long
    For i = 1 To Len(s)
        If AscW(Mid$(s, i, 1)) > 255 Then n = n + 2 Else n = n + 1
    Next i
    HK_TextUnits = n
End Function

Private Sub HK_WriteUtf8File(ByVal path As String, ByVal content As String)
    Dim st As Object
    Set st = CreateObject("ADODB.Stream")
    st.Type = 2: st.Charset = "utf-8": st.Open
    st.WriteText content
    st.SaveToFile path, 2
    st.Close
End Sub

Private Function HK_ReadUtf8File(ByVal path As String) As String
    Dim st As Object
    Set st = CreateObject("ADODB.Stream")
    st.Type = 2: st.Charset = "utf-8": st.Open
    st.LoadFromFile path
    HK_ReadUtf8File = st.ReadText(-1)
    st.Close
End Function

' OCR °á°ú: ¹èÀ²¸¶´Ù "S<TAB>¹èÀ²" µÚ¿¡ ´Ü¾î "W<TAB>ÁÙ¹øÈ£<TAB>±ÛÀÚ<TAB>x<TAB>y<TAB>Æø<TAB>³ôÀÌ"(¿øº» ÁÂÇ¥), ÁÙ "L<TAB>ÁÙ±ÛÀÚ"
' ¹èÀ²¿¡ µû¶ó ÀÐÈ÷´Â ±ÛÀÚ°¡ ´Þ¶ó 1.4¡¤1.2¡¤1.0¡¤1.7¡¤2.0 ¹è·Î °¢°¢ ÀÐ°í ¸ðµÎ Ç¥·Î µî·ÏÇÑ´Ù(¾Õ ¹èÀ²ºÎÅÍ °Ë»ö)
Private Function HK_OcrScript() As String
    Dim s As String
    s = s & "param($path, $out, $lang=""ko"")" & vbCrLf
    s = s & "try {" & vbCrLf
    s = s & "Add-Type -AssemblyName System.Runtime.WindowsRuntime" & vbCrLf
    s = s & "$null = [Windows.Media.Ocr.OcrEngine, Windows.Foundation, ContentType=WindowsRuntime]" & vbCrLf
    s = s & "$null = [Windows.Storage.StorageFile, Windows.Storage, ContentType=WindowsRuntime]" & vbCrLf
    s = s & "$null = [Windows.Graphics.Imaging.BitmapDecoder, Windows.Graphics.Imaging, ContentType=WindowsRuntime]" & vbCrLf
    s = s & "$null = [Windows.Globalization.Language, Windows.Globalization, ContentType=WindowsRuntime]" & vbCrLf
    s = s & "$g = ([System.WindowsRuntimeSystemExtensions].GetMethods() | Where-Object { $_.Name -eq 'AsTask' -and $_.GetParameters().Count -eq 1 -and $_.GetParameters()[0].ParameterType.Name -eq 'IAsyncOperation`1' })[0]" & vbCrLf
    s = s & "function Await($op, $type){ $t=$g.MakeGenericMethod($type).Invoke($null,@($op)); $t.Wait(-1) | Out-Null; $t.Result }" & vbCrLf
    s = s & "$eng = [Windows.Media.Ocr.OcrEngine]::TryCreateFromLanguage((New-Object Windows.Globalization.Language($lang)))" & vbCrLf
    s = s & "if (-not $eng) { $eng = [Windows.Media.Ocr.OcrEngine]::TryCreateFromUserProfileLanguages() }" & vbCrLf
    s = s & "if (-not $eng) { throw ""OCR engine not available"" }" & vbCrLf
    s = s & "Add-Type -AssemblyName System.Drawing" & vbCrLf
    s = s & "$src = [System.Drawing.Image]::FromFile($path)" & vbCrLf
    s = s & "$lines = @()" & vbCrLf
    s = s & "foreach ($scale in @(1.4, 1.2, 1.0, 1.7, 2.0)) {" & vbCrLf
    s = s & "  $nw = [int]($src.Width * $scale); $nh = [int]($src.Height * $scale)" & vbCrLf
    s = s & "  if ($nw -gt 6000 -or $nh -gt 6000) { continue }" & vbCrLf
    s = s & "  $bmp = New-Object System.Drawing.Bitmap $nw, $nh" & vbCrLf
    s = s & "  $gr = [System.Drawing.Graphics]::FromImage($bmp); $gr.InterpolationMode = [System.Drawing.Drawing2D.InterpolationMode]::HighQualityBicubic" & vbCrLf
    s = s & "  $gr.DrawImage($src, 0, 0, $nw, $nh); $gr.Dispose()" & vbCrLf
    s = s & "  $tmpPng = [IO.Path]::Combine([IO.Path]::GetTempPath(), 'busan_ocr_' + [IO.Path]::GetRandomFileName() + '.png')" & vbCrLf
    s = s & "  $bmp.Save($tmpPng, [System.Drawing.Imaging.ImageFormat]::Png); $bmp.Dispose()" & vbCrLf
    s = s & "  $file = Await ([Windows.Storage.StorageFile]::GetFileFromPathAsync($tmpPng)) ([Windows.Storage.StorageFile])" & vbCrLf
    s = s & "  $stream = Await ($file.OpenAsync([Windows.Storage.FileAccessMode]::Read)) ([Windows.Storage.Streams.IRandomAccessStream])" & vbCrLf
    s = s & "  $dec = Await ([Windows.Graphics.Imaging.BitmapDecoder]::CreateAsync($stream)) ([Windows.Graphics.Imaging.BitmapDecoder])" & vbCrLf
    s = s & "  $sb = Await ($dec.GetSoftwareBitmapAsync()) ([Windows.Graphics.Imaging.SoftwareBitmap])" & vbCrLf
    s = s & "  $res = Await ($eng.RecognizeAsync($sb)) ([Windows.Media.Ocr.OcrResult])" & vbCrLf
    s = s & "  $stream.Dispose(); Remove-Item $tmpPng -ErrorAction SilentlyContinue" & vbCrLf
    s = s & "  $lines += ('S' + [char]9 + $scale); $li = 0" & vbCrLf
    s = s & "  foreach ($l in $res.Lines) { $li++; $lines += ('L' + [char]9 + $l.Text); foreach ($w in $l.Words) { $b = $w.BoundingRect; $lines += ('W' + [char]9 + $li + [char]9 + $w.Text + [char]9 + [int]($b.X / $scale) + [char]9 + [int]($b.Y / $scale) + [char]9 + [int]($b.Width / $scale) + [char]9 + [int]($b.Height / $scale)) } }" & vbCrLf
    s = s & "}" & vbCrLf
    s = s & "$src.Dispose()" & vbCrLf
    s = s & "[IO.File]::WriteAllText($out, ($lines -join ""`n""), (New-Object Text.UTF8Encoding($false)))" & vbCrLf
    s = s & "} catch { [IO.File]::WriteAllText($out, ""ERROR "" + $_.Exception.Message, (New-Object Text.UTF8Encoding($false))) }" & vbCrLf
    HK_OcrScript = s
End Function

' [v2.7] OCR ¿Àµ¶ º¸Á¤: ±Û s ¾È¿¡ Å°¿öµå(3ÀÚ ÀÌ»ó)¿Í ±æÀÌ°¡ °°°í ÇÑ ±ÛÀÚ¸¸ ´Ù¸¥ Á¶°¢ÀÌ ÀÖÀ¸¸é ±× Á¶°¢À» Å°¿öµå·Î ¹Ù²ã µ¹·ÁÁØ´Ù
'   ¼ýÀÚ ÀÚ¸®´Â Á¤È®È÷ °°¾Æ¾ß ÇÔ ¡æ "Å°¿öµå2"°¡ "Å°¿öµå1"·Î ¹Ù²î°Å³ª "010-1234" °°Àº °ªÀÌ Å°¿öµå·Î ¿ÀÀεÇÁö ¾Ê°Ô
Private Function HK_FuzzyFix(ByVal s As String, ByVal kw As String) As String
    Dim i As Long, j As Long, n As Long, W As String, diff As Long, cH As String, kc As String, bad As Boolean
    HK_FuzzyFix = s
    n = Len(kw)
    If n < 3 Then Exit Function
    If InStr(1, s, kw, vbTextCompare) > 0 Then Exit Function
    For i = 1 To Len(s) - n + 1
        W = Mid$(s, i, n)
        diff = 0: bad = False
        For j = 1 To n
            cH = Mid$(W, j, 1): kc = Mid$(kw, j, 1)
            If StrComp(cH, kc, vbTextCompare) <> 0 Then
                If (cH Like "#") Or (kc Like "#") Then bad = True: Exit For
                diff = diff + 1
                If diff > 1 Then Exit For
            End If
        Next j
        If Not bad And diff = 1 Then
            HK_FuzzyFix = Left$(s, i - 1) & kw & Mid$(s, i + n)
            Exit Function
        End If
    Next i
End Function

' 09-29: ¿­ ³Êºñ »óÇÑ 60, ³ÑÄ¡´Â ±ÛÀº ÁÙ ¹Ù²Þ(¼¿ ¸ÂÃã)
Private Sub HK_CapWidths(ws As Worksheet)
    Dim c As Long, lastCol As Long
    On Error Resume Next
    lastCol = KW_LAST_COL
    If ws.Columns("A").ColumnWidth > 60 Then ws.Columns("A").ColumnWidth = 60
    For c = KW_FIRST_COL To lastCol
        If ws.Columns(c).ColumnWidth > 60 Then
            ws.Columns(c).ColumnWidth = 60
            ws.Range(ws.cells(4, c), ws.cells(ws.rows.Count, c).End(xlUp)).WrapText = True
        End If
    Next c
    ws.Range("A2").WrapText = False
    ws.Range(ws.cells(4, 1), ws.cells(ws.rows.Count, 1).End(xlUp)).WrapText = True
    ws.rows("4:" & ws.cells(ws.rows.Count, 1).End(xlUp).row).VerticalAlignment = xlTop
    On Error GoTo 0
End Sub